home *** CD-ROM | disk | FTP | other *** search
/ 100 Best Shareware & Freeware Games / 100 Games.iso / Cards / PySol / pysol460.exe / {app} / python / DLLs / tk8.3 / safetk.tcl < prev    next >
Encoding:
Text File  |  2001-07-27  |  7.1 KB  |  273 lines
  1. # safetk.tcl --
  2. #
  3. # Support procs to use Tk in safe interpreters.
  4. #
  5. # RCS: @(#) $Id: safetk.tcl,v 1.6 2000/04/08 06:59:28 hobbs Exp $
  6. #
  7. # Copyright (c) 1997 Sun Microsystems, Inc.
  8. #
  9. # See the file "license.terms" for information on usage and redistribution
  10. # of this file, and for a DISCLAIMER OF ALL WARRANTIES.
  11.  
  12. # see safetk.n for documentation
  13.  
  14. #
  15. #
  16. # Note: It is now ok to let untrusted code being executed
  17. #       between the creation of the interp and the actual loading
  18. #       of Tk in that interp because the C side Tk_Init will
  19. #       now look up the master interp and ask its safe::TkInit
  20. #       for the actual parameters to use for it's initialization (if allowed),
  21. #       not relying on the slave state.
  22. #
  23.  
  24. # We use opt (optional arguments parsing)
  25. package require opt 0.4.1;
  26.  
  27. namespace eval ::safe {
  28.  
  29.     # counter for safe toplevels
  30.     variable tkSafeId 0;
  31.  
  32.     #
  33.     # tkInterpInit : prepare the slave interpreter for tk loading
  34.     #                most of the real job is done by loadTk
  35.     # returns the slave name (tkInterpInit does)
  36.     #
  37.     proc ::safe::tkInterpInit {slave argv} {
  38.     global env tk_library
  39.  
  40.     # Clear Tk's access for that interp (path).
  41.     allowTk $slave $argv
  42.  
  43.     # there seems to be an obscure case where the tk_library
  44.     # variable value is changed to point to a sym link destination
  45.     # dir instead of the sym link itself, and thus where the $tk_library
  46.     # would then not be anymore one of the auto_path dir, so we use
  47.     # the addToAccessPath which adds if it's not already in instead
  48.     # of the more conventional findInAccessPath.
  49.     # Might be usefull for masters without Tk really loaded too.
  50.     ::interp eval $slave [list set tk_library [::safe::interpAddToAccessPath $slave $tk_library]]
  51.     return $slave
  52.     }
  53.  
  54.  
  55. # tkInterpLoadTk : 
  56. # Do additional configuration as needed (calling tkInterpInit) 
  57. # and actually load Tk into the slave.
  58. # 
  59. # Either contained in the specified windowId (-use) or
  60. # creating a decorated toplevel for it.
  61.  
  62. # empty definition for auto_mkIndex
  63. proc ::safe::loadTk {} {}
  64.    
  65. ::tcl::OptProc loadTk {
  66.     {slave -interp "name of the slave interpreter"}
  67.     {-use  -windowId {} "window Id to use (new toplevel otherwise)"}
  68.     {-display -displayName {} "display name to use (current one otherwise)"}
  69. } {
  70.     set displayGiven [::tcl::OptProcArgGiven "-display"]
  71.     if {!$displayGiven} {
  72.     
  73.     # Try to get the current display from "."
  74.     # (which might not exist if the master is tk-less)
  75.     
  76.     if {[catch {set display [winfo screen .]}]} {
  77.         if {[info exists ::env(DISPLAY)]} {
  78.         set display $::env(DISPLAY)
  79.         } else {
  80.         Log $slave "no winfo screen . nor env(DISPLAY)" WARNING
  81.         set display ":0.0"
  82.         }
  83.     }
  84.     }
  85.     if {![::tcl::OptProcArgGiven "-use"]} {
  86.     
  87.     # create a decorated toplevel
  88.     
  89.     ::tcl::Lassign [tkTopLevel $slave $display] w use
  90.  
  91.     # set our delete hook (slave arg is added by interpDelete)
  92.     # to clean up both window related code and tkInit(slave)
  93.     Set [DeleteHookName $slave] [list tkDelete {} $w]
  94.  
  95.     } else {
  96.  
  97.     # set our delete hook (slave arg is added by interpDelete)
  98.     # to clean up tkInit(slave)
  99.         
  100.     Set [DeleteHookName $slave] [list disallowTk]
  101.  
  102.     # Let's be nice and also accept tk window names instead of ids
  103.     
  104.     if {[string match ".*" $use]} {
  105.         set windowName $use
  106.         set use [winfo id $windowName]
  107.         set nDisplay [winfo screen $windowName]
  108.     } else {
  109.  
  110.         # Check for a better -display value
  111.         # (works only for multi screens on single host, but not
  112.         #  cross hosts, for that a tk window name would be better
  113.         #  but embeding is also usefull for non tk names)
  114.         
  115.         if {![catch {winfo pathname $use} name]} {
  116.         set nDisplay [winfo screen $name]
  117.         } else {
  118.  
  119.         # Can't have a better one
  120.         
  121.         set nDisplay $display
  122.         }
  123.     }
  124.     if {[string compare $nDisplay $display]} {
  125.         if {$displayGiven} {
  126.         error "conflicting -display $display and -use\
  127.             $use -> $nDisplay"
  128.         } else {
  129.         set display $nDisplay
  130.         }
  131.     }
  132.     }
  133.  
  134.     # Prepares the slave for tk with those parameters
  135.     
  136.     tkInterpInit $slave [list "-use" $use "-display" $display]
  137.     
  138.     load {} Tk $slave
  139.  
  140.     return $slave
  141. }
  142.  
  143. proc ::safe::TkInit {interpPath} {
  144.     variable tkInit
  145.     if {[info exists tkInit($interpPath)]} {
  146.     set value $tkInit($interpPath)
  147.     Log $interpPath "TkInit called, returning \"$value\"" NOTICE
  148.     return $value
  149.     } else {
  150.     Log $interpPath "TkInit called for interp with clearance:\
  151.         preventing Tk init" ERROR
  152.     error "not allowed"
  153.     }
  154. }
  155.  
  156. # safe::allowTk --
  157. #
  158. #    Set tkInit(interpPath) to allow Tk to be initialized in
  159. #    safe::TkInit.
  160. #
  161. # Arguments:
  162. #    interpPath    slave interpreter handle
  163. #    argv        arguments passed to safe::TkInterpInit
  164. #
  165. # Results:
  166. #    none.
  167.  
  168. proc ::safe::allowTk {interpPath argv} {
  169.     variable tkInit
  170.     set tkInit($interpPath) $argv
  171.     return
  172. }
  173.  
  174.  
  175. # safe::disallowTk --
  176. #
  177. #    Unset tkInit(interpPath) to disallow Tk from getting initialized
  178. #    in safe::TkInit.
  179. #
  180. # Arguments:
  181. #    interpPath    slave interpreter handle
  182. #
  183. # Results:
  184. #    none.
  185.  
  186. proc ::safe::disallowTk {interpPath} {
  187.     variable tkInit
  188.     # This can already be deleted by the DeleteHook of the interp
  189.     if {[info exists tkInit($interpPath)]} {
  190.     unset tkInit($interpPath)
  191.     }
  192.     return
  193. }
  194.  
  195.  
  196. # safe::tkDelete --
  197. #
  198. #    Clean up the window associated with the interp being deleted.
  199. #
  200. # Arguments:
  201. #    interpPath    slave interpreter handle
  202. #
  203. # Results:
  204. #    none.
  205.  
  206. proc ::safe::tkDelete {W window slave} {
  207.  
  208.     # we are going to be called for each widget... skip untill it's
  209.     # top level
  210.  
  211.     Log $slave "Called tkDelete $W $window" NOTICE
  212.     if {[::interp exists $slave]} {
  213.     if {[catch {::safe::interpDelete $slave} msg]} {
  214.         Log $slave "Deletion error : $msg"
  215.     }
  216.     }
  217.     if {[winfo exists $window]} {
  218.     Log $slave "Destroy toplevel $window" NOTICE
  219.     destroy $window
  220.     }
  221.     
  222.     # clean up tkInit(slave)
  223.     disallowTk $slave
  224.     return
  225. }
  226.  
  227. proc ::safe::tkTopLevel {slave display} {
  228.     variable tkSafeId
  229.     incr tkSafeId
  230.     set w ".safe$tkSafeId"
  231.     if {[catch {toplevel $w -screen $display -class SafeTk} msg]} {
  232.     return -code error "Unable to create toplevel for\
  233.         safe slave \"$slave\" ($msg)"
  234.     }
  235.     Log $slave "New toplevel $w" NOTICE
  236.  
  237.     set msg "Untrusted Tcl applet ($slave)"
  238.     wm title $w $msg
  239.  
  240.     # Control frame
  241.     set wc $w.fc
  242.     frame $wc -bg red -borderwidth 3 -relief ridge
  243.  
  244.     # We will destroy the interp when the window is destroyed
  245.     bindtags $wc [concat Safe$wc [bindtags $wc]]
  246.     bind Safe$wc <Destroy> [list ::safe::tkDelete %W $w $slave]
  247.  
  248.     label $wc.l -text $msg -padx 2 -pady 0 -anchor w
  249.  
  250.     # We want the button to be the last visible item
  251.     # (so be packed first) and at the right and not resizing horizontally
  252.  
  253.     # frame the button so it does not expand horizontally
  254.     # but still have the default background instead of red one from the parent
  255.     frame  $wc.fb -bd 0
  256.     button $wc.fb.b -text "Delete" \
  257.         -bd 1  -padx 2 -pady 0 -highlightthickness 0 \
  258.         -command [list ::safe::tkDelete $w $w $slave]
  259.     pack $wc.fb.b -side right -fill both
  260.     pack $wc.fb -side right -fill both -expand 1
  261.     pack $wc.l -side left  -fill both -expand 1
  262.     pack $wc -side bottom -fill x
  263.  
  264.     # Container frame
  265.     frame $w.c -container 1
  266.     pack $w.c -fill both -expand 1
  267.     
  268.     # return both the toplevel window name and the id to use for embedding
  269.     list $w [winfo id $w.c]
  270. }
  271.  
  272. }
  273.